這些常式和系統 C 函式庫中的對應常式相同。在清單內容中，各種 get 常式的回傳值如下：
# 0 1 2 3 4
my ( $name, $passwd, $gid, $members ) = getgr*
my ( $name, $aliases, $addrtype, $net ) = getnet*
my ( $name, $aliases, $port, $proto ) = getserv*
my ( $name, $aliases, $proto ) = getproto*
my ( $name, $aliases, $addrtype, $length, @addrs ) = gethost*
my ( $name, $passwd, $uid, $gid, $quota,
$comment, $gcos, $dir, $shell, $expire ) = getpw*
# 5 6 7 8 9(如果條目不存在，回傳值為單一無意義的 true 值。)
$gcos 欄位的確切意義會有所不同，但通常會包含使用者的真實姓名（與登入名稱相對）和與使用者相關的其他資訊。但請注意，在許多系統中，使用者可以變更這些資訊，因此無法信賴，因此 $gcos 會受到污染（請參閱 perlsec）。$passwd 和 $shell，使用者的加密密碼和登入 shell，也會受到污染，原因相同。
在純量內容中，您會取得名稱，除非函式是依名稱查詢，否則您會取得其他項目，無論是什麼項目。（如果條目不存在，您會取得未定義的值。）例如
my $uid = getpwnam($name);
my $name = getpwuid($num);
my $name = getpwent();
my $gid = getgrnam($name);
my $name = getgrgid($num);
my $name = getgrent();
# etc.在 getpw*() 中，$quota、$comment 和 $expire 欄位很特別，因為它們在許多系統中不受支援。如果 $quota 不受支援，它會是一個空的純量。如果它受支援，它通常會編碼磁碟配額。如果 $comment 欄位不受支援，它會是一個空的純量。如果它受支援，它通常會編碼一些關於使用者的管理評論。在某些系統中，$quota 欄位可能是 $change 或 $age，這些欄位與密碼老化有關。在某些系統中，$comment 欄位可能是 $class。$expire 欄位（如果存在）會編碼帳戶或密碼的到期期間。有關這些欄位在您的系統中的可用性和確切意義，請參閱 getpwnam(3) 和您系統的 pwd.h 檔案。您也可以透過 Perl 找出 $quota 和 $comment 欄位的意義，以及您是否有 $expire 欄位，方法是使用 Config 模組和值 d_pwquota、d_pwage、d_pwchange、d_pwcomment 和 d_pwexpire。只有當您的廠商以直覺的方式實作影子密碼檔案時，才會支援影子密碼檔案，也就是說，如果您在特權下執行，或存在 shadow(3) 函式（如 System V 中所見，包括 Solaris 和 Linux），則呼叫一般 C 函式庫常式會取得影子版本。實作專有影子密碼設施的系統不太可能受到支援。
getgr*() 傳回的 $members 值是群組成員的登入名稱，以空白分隔。
對於 gethost*() 函數，如果 C 中支援 h_errno 變數，函數呼叫失敗時，它會透過 $? 傳回給您。成功呼叫傳回的 @addrs 值是對應函式庫呼叫傳回的原始位址清單。在網際網路網域中，每個位址長度為四個位元組；您可以透過類似以下方式解壓縮
my ($w,$x,$y,$z) = unpack('W4',$addr[0]);Socket 函式庫讓這件事變得更簡單
use Socket;
my $iaddr = inet_aton("127.1"); # or whatever address
my $name = gethostbyaddr($iaddr, AF_INET);
# or going the other way
my $straddr = inet_ntoa($iaddr);相反地，要將主機名稱解析為 IP 位址，您可以撰寫以下程式碼
use Socket;
my $packed_ip = gethostbyname("www.perl.org");
my $ip_address;
if (defined $packed_ip) {
$ip_address = inet_ntoa($packed_ip);
}請確定在 SCALAR 背景下呼叫 gethostbyname，並檢查其傳回值是否已定義。
getprotobynumber 函數即使只接受一個引數，但具有清單運算子的優先權，因此請小心
getprotobynumber $number eq 'icmp' # WRONG
getprotobynumber($number eq 'icmp') # actually means this
getprotobynumber($number) eq 'icmp' # better this way如果您記不住傳回清單的哪個元素包含哪個傳回值，標準模組中提供了依名稱介面：File::stat、Net::hostent、Net::netent、Net::protoent、Net::servent、Time::gmtime、Time::localtime 和 User::grent。這些會覆寫一般的內建函數，提供傳回物件的版本，每個欄位都有適當的名稱。例如
use File::stat;
use User::pwent;
my $is_his = (stat($filename)->uid == pwent($whoever)->uid);即使看起來它們是相同的函式呼叫 (uid)，但它們並非如此，因為 File::stat 物件與 User::pwent 物件不同。
在多執行緒環境中，其中有多個執行緒可以使用這些函數，許多函數並不安全。特別是像 getpwent() 之類的函數會逐處理序反覆執行，而不是逐執行緒反覆執行，因此如果兩個執行緒同時反覆執行，兩者都無法取得所有記錄。
有些系統有某些函數的執行緒安全版本，例如 getpwnam_r() 取代 getpwnam()。在此，Perl 會自動且無形地替換為執行緒安全版本，而不會通知您。這表示在某些系統上安全執行的程式碼，可能會在缺少執行緒安全版本的其他系統上失敗。