內容

• 名稱
• 語法
• 說明
• 功能介面
  • bunzip2 $input_filename_or_reference => $output_filename_or_reference [, OPTS]
    • $input_filename_or_reference 參數
    • $output_filename_or_reference 參數
  • 注意事項
  • 選用參數
  • 範例
• 物件導向介面
  • 建構函式
  • 建構函式選項
  • 範例
• 方法
  • read
  • read
  • getline
  • getc
  • ungetc
  • getHeaderInfo
  • tell
  • eof
  • seek
  • binmode
  • opened
  • autoflush
  • input_line_number
  • fileno
  • close
  • nextStream
  • trailingData
• 匯入
• 範例
  • 與 Net::FTP 搭配使用
• 支援
• 另請參閱
• 作者
• 修改記錄
• 版權與授權

#名稱

IO::Uncompress::Bunzip2 - 讀取 bzip2 檔案/緩衝區

#語法

use IO::Uncompress::Bunzip2 qw(bunzip2 $Bunzip2Error) ;

my $status = bunzip2 $input => $output [,OPTS]
    or die "bunzip2 failed: $Bunzip2Error\n";

my $z = IO::Uncompress::Bunzip2->new( $input [OPTS] )
    or die "bunzip2 failed: $Bunzip2Error\n";

$status = $z->read($buffer)
$status = $z->read($buffer, $length)
$status = $z->read($buffer, $length, $offset)
$line = $z->getline()
$char = $z->getc()
$char = $z->ungetc()
$char = $z->opened()

$data = $z->trailingData()
$status = $z->nextStream()
$data = $z->getHeaderInfo()
$z->tell()
$z->seek($position, $whence)
$z->binmode()
$z->fileno()
$z->eof()
$z->close()

$Bunzip2Error ;

# IO::File mode

<$z>
read($z, $buffer);
read($z, $buffer, $length);
read($z, $buffer, $length, $offset);
tell($z)
seek($z, $position, $whence)
binmode($z)
fileno($z)
eof($z)
close($z)

#說明

此模組提供一個 Perl 介面，讓使用者可以讀取 bzip2 檔案/緩衝區。

若要寫入 bzip2 檔案/緩衝區，請參閱配套模組 IO::Compress::Bzip2。

#函數式介面

頂層函式 bunzip2 用於執行緩衝區和/或檔案之間的「一次性」解壓縮。若要更精細地控制解壓縮程序，請參閱 「物件導向介面」 區段。

use IO::Uncompress::Bunzip2 qw(bunzip2 $Bunzip2Error) ;

bunzip2 $input_filename_or_reference => $output_filename_or_reference [,OPTS]
    or die "bunzip2 failed: $Bunzip2Error\n";

函數式介面需要 Perl5.005 或更新版本。

#bunzip2 $input_filename_or_reference => $output_filename_or_reference [, OPTS]

bunzip2 至少需要兩個參數，$input_filename_or_reference 和 $output_filename_or_reference，以及零個或多個選用參數（請參閱 「選用參數」）

#$input_filename_or_reference 參數

參數 $input_filename_or_reference 用於定義壓縮資料的來源。

它可以採用下列其中一種形式

#檔案名稱

如果 $input_filename_or_reference 參數是單純的純量，則假設它是一個檔案名稱。此檔案將會開啟以供讀取，且輸入資料將從中讀取。

#檔案控制代碼

如果 $input_filename_or_reference 參數是檔案控制代碼，則輸入資料將從中讀取。字串「-」可用作標準輸入的別名。

#純量參考

如果 $input_filename_or_reference 是純量參考，則輸入資料將從 $$input_filename_or_reference 讀取。

#陣列參考

如果 $input_filename_or_reference 是陣列參考，則陣列中的每個元素都必須是檔案名稱。

輸入資料將從每個檔案依序讀取。

將會遍歷整個陣列，以確保在解壓縮任何資料前，它只包含有效的檔案名稱。

#輸入檔案 FileGlob 字串

如果 $input_filename_or_reference 是由字元「<」和「>」分隔的字串，bunzip2 會假設它是一個輸入檔案 FileGlob 字串。輸入是與 FileGlob 匹配的檔案清單。

有關更多詳細資訊，請參閱 File::GlobMapper。

如果 $input_filename_or_reference 參數是任何其他類型，則會傳回 undef。

#$output_filename_or_reference 參數

參數 $output_filename_or_reference 用於控制未壓縮資料的目的地。此參數可以採用下列其中一種形式。

#檔案名稱

如果 $output_filename_or_reference 參數是一個簡單的純量，則假設它是一個檔案名稱。此檔案將會開啟進行寫入，而未壓縮的資料將會寫入其中。

#檔案控制代碼

如果 $output_filename_or_reference 參數是一個檔案控制代碼，則未壓縮的資料將會寫入其中。字串「-」可以用作標準輸出的別名。

#純量參照

如果 $output_filename_or_reference 是純量參照，則未壓縮的資料將會儲存在 $$output_filename_or_reference 中。

#陣列參照

如果 $output_filename_or_reference 是陣列參照，則未壓縮的資料將會推送到陣列中。

#輸出檔案 Glob

如果 $output_filename_or_reference 是由字元「<」和「>」分隔的字串，bunzip2 會假設它是一個輸出檔案 Glob 字串。輸出是與檔案 Glob 相符的檔案清單。

當 $output_filename_or_reference 是檔案 Glob 字串時，$input_filename_or_reference 也必須是檔案 Glob 字串。其他任何情況都是錯誤。

有關更多詳細資訊，請參閱 File::GlobMapper。

如果 $output_filename_or_reference 參數是任何其他類型，則會傳回 undef。

#注意事項

當 $input_filename_or_reference 對應到多個壓縮檔案/緩衝區，而 $output_filename_or_reference 是單一檔案/緩衝區時，在解壓縮後，$output_filename_or_reference 將會包含來自每個輸入檔案/緩衝區的所有未壓縮資料的串接。

#選用參數

一次性函數 bunzip2 的選用參數（大部分）與在 「建構函數選項」區段中定義的 OO 介面中使用的參數相同。例外如下所列

#AutoClose => 0|1

此選項適用於任何輸入或輸出資料串流到 bunzip2 的檔案控制代碼。

如果指定了 AutoClose，且值為 true，則會導致在 bunzip2 完成後關閉所有輸入和/或輸出檔案控制代碼。

此參數預設為 0。

#BinModeOut => 0|1

此選項現在為無操作。所有檔案都將以二進位模式寫入。

#Append => 0|1

此選項的行為取決於輸出資料串流的類型。

• 一個 Buffer

  如果啟用 Append，所有未壓縮的資料都將附加到輸出緩衝區的結尾。否則，在將任何未壓縮的資料寫入輸出緩衝區之前，將會清除輸出緩衝區。

• 一個檔案名稱

  如果啟用 Append，檔案將以附加模式開啟。否則，在將任何未壓縮的資料寫入檔案之前，將會截斷檔案的內容（如果有的話）。

• 一個檔案處理常式

  如果啟用 Append，在將任何未壓縮的資料寫入檔案處理常式之前，將透過呼叫 seek 將檔案處理常式定位到檔案的結尾。否則，不會移動檔案指標。

當指定 Append 並將其設定為 true 時，它會將所有未壓縮的資料附加到輸出資料串流。

因此，當輸出是檔案處理常式時，它會在寫入任何未壓縮的資料之前執行 seek 到 eof。如果輸出是檔案名稱，它將開啟以進行附加。如果輸出是緩衝區，所有未壓縮的資料都將附加到現有的緩衝區。

相反地，當未指定 Append，或它存在且設定為 false 時，它將執行以下操作。

當輸出是檔案名稱時，它會在寫入任何未壓縮的資料之前截斷檔案的內容。如果輸出是檔案處理常式，則其位置不會改變。如果輸出是緩衝區，它將在輸出任何未壓縮的資料之前被清除。

預設為 0。

#MultiStream => 0|1

如果輸入檔案/緩衝區包含多個壓縮資料串流，此選項將解壓縮所有資料作為單一資料串流。

預設為 0。

#TrailingData => $scalar

在解壓縮完成後，傳回壓縮資料串流後立即存在的資料（如果有的話）。

當壓縮資料串流後立即有有用的資訊，而且您不知道壓縮資料串流的長度時，可以使用此選項。

如果輸入是緩衝區，trailingData 將傳回從壓縮資料串流的結尾到緩衝區結尾的所有內容。

如果輸入是檔案句柄，trailingData 會傳回壓縮資料串流結束後留在檔案句柄輸入緩衝區的資料。接著你可以使用檔案句柄來讀取輸入檔案的其餘部分。

如果輸入是檔案名稱，請勿使用 trailingData。

如果你在開始解壓縮前知道壓縮資料串流的長度，你可以透過設定 InputLength 選項來避免使用 trailingData。

#範例

讀取檔案 file1.txt.bz2 的內容，並將解壓縮的資料寫入檔案 file1.txt。

use strict ;
use warnings ;
use IO::Uncompress::Bunzip2 qw(bunzip2 $Bunzip2Error) ;

my $input = "file1.txt.bz2";
my $output = "file1.txt";
bunzip2 $input => $output
    or die "bunzip2 failed: $Bunzip2Error\n";

從現有的 Perl 檔案句柄 $input 讀取，並將解壓縮的資料寫入緩衝區 $buffer。

use strict ;
use warnings ;
use IO::Uncompress::Bunzip2 qw(bunzip2 $Bunzip2Error) ;
use IO::File ;

my $input = IO::File->new( "<file1.txt.bz2" )
    or die "Cannot open 'file1.txt.bz2': $!\n" ;
my $buffer ;
bunzip2 $input => \$buffer
    or die "bunzip2 failed: $Bunzip2Error\n";

解壓縮目錄 "/my/home" 中所有符合 "*.txt.bz2" 的檔案，並將壓縮資料儲存在同一個目錄中

use strict ;
use warnings ;
use IO::Uncompress::Bunzip2 qw(bunzip2 $Bunzip2Error) ;

bunzip2 '</my/home/*.txt.bz2>' => '</my/home/#1.txt>'
    or die "bunzip2 failed: $Bunzip2Error\n";

如果你想要一次壓縮一個檔案，這個方法可以達成

use strict ;
use warnings ;
use IO::Uncompress::Bunzip2 qw(bunzip2 $Bunzip2Error) ;

for my $input ( glob "/my/home/*.txt.bz2" )
{
    my $output = $input;
    $output =~ s/.bz2// ;
    bunzip2 $input => $output
        or die "Error compressing '$input': $Bunzip2Error\n";
}

#OO 介面

#建構函式

IO::Uncompress::Bunzip2 的建構函式的格式如下所示

my $z = IO::Uncompress::Bunzip2->new( $input [OPTS] )
    or die "IO::Uncompress::Bunzip2 failed: $Bunzip2Error\n";

成功時傳回 IO::Uncompress::Bunzip2 物件，失敗時傳回 undef。變數 $Bunzip2Error 會在失敗時包含錯誤訊息。

如果你執行的是 Perl 5.005 或更新版本，IO::Uncompress::Bunzip2 傳回的物件 $z 可以像 IO::File 檔案句柄一樣使用。這表示你可以使用 $z 執行所有正常的輸入檔案操作。例如，你可以使用下列任何一種格式從壓縮檔案/緩衝區讀取一行

$line = $z->getline();
$line = <$z>;

強制參數 $input 用於判斷壓縮資料的來源。這個參數可以採用下列三種格式之一。

#檔案名稱

如果 $input 參數是純量，則假設它是一個檔案名稱。這個檔案會開啟為讀取模式，並從中讀取壓縮資料。

#檔案句柄

如果 $input 參數是檔案句柄，則會從中讀取壓縮資料。字串 '-' 可以用作標準輸入的別名。

#純量參考

如果 $input 是純量參考，則會從 $$input 讀取壓縮資料。

#建構函式選項

以下定義的選項名稱不區分大小寫，且可以選擇性地加上前綴「-」。因此，下列所有選項皆有效

-AutoClose
-autoclose
AUTOCLOSE
autoclose

OPTS 是下列選項的組合

#AutoClose => 0|1

此選項僅在 $input 參數為檔案控制代碼時有效。如果指定，且值為 true，則會在呼叫 close 方法或銷毀 IO::Uncompress::Bunzip2 物件後關閉檔案。

此參數預設為 0。

#MultiStream => 0|1

允許將多個串接壓縮串流視為單一壓縮串流。解壓縮會在下列情況之一發生時停止：到達檔案/緩衝區的結尾、遇到錯誤（過早的檔案結尾、損毀的壓縮資料）或串流的結尾未立即接續另一個串流的開頭。

此參數預設為 0。

#Prime => $string

此選項會在處理輸入檔案/緩衝區之前解壓縮 $string 的內容。

此選項在壓縮資料嵌入在另一個檔案/資料結構中，且無法在不讀取前幾個位元組的情況下找出壓縮資料開頭時很有用。如果是這種情況，可以使用此選項使用這些位元組「啟動」解壓縮。

#Transparent => 0|1

如果設定此選項，且輸入檔案/緩衝區不是壓縮資料，模組仍會允許讀取。

此外，如果輸入檔案/緩衝區確實包含壓縮資料，且其後方緊接非壓縮資料，設定此選項會讓此模組將整個檔案/緩衝區視為單一資料串流。

此選項預設為 1。

#BlockSize => $num

讀取壓縮輸入資料時，IO::Uncompress::Bunzip2 會以 $num 位元組為單位讀取。

此選項預設為 4096。

#InputLength => $size

如果存在，此選項會將從輸入檔案/緩衝區讀取的壓縮位元組數量限制為 $size。可以在壓縮資料串流後方有有用資料，且您事先知道壓縮資料串流的精確長度的情況下使用此選項。

此選項大多用於從檔案句柄讀取時，此時檔案指標會停留在壓縮資料串流之後的第一個位元組。

此選項預設為關閉。

#Append => 0|1

此選項控制 read 方法對未壓縮資料的處理方式。

如果設定為 1，所有未壓縮資料會附加到 read 方法的輸出參數。

如果設定為 0，read 方法的輸出參數的內容會被未壓縮資料覆寫。

預設為 0。

#Strict => 0|1

此選項為無操作。

#Small => 0|1

當非零時，此選項會讓 bzip2 使用解壓縮演算法，此演算法會使用較少的記憶體，但會增加解壓縮所需的時間。

預設為 0。

#範例

待辦事項

#方法

#read

用法為

$status = $z->read($buffer)

讀取一個壓縮資料區塊（壓縮區塊的大小由建構函式中的 Buffer 選項決定），解壓縮它，並將任何未壓縮資料寫入 $buffer。如果在建構函式中設定 Append 參數，未壓縮資料會附加到 $buffer 參數。否則，$buffer 會被覆寫。

傳回寫入 $buffer 的未壓縮位元組數，如果為檔案結束或發生錯誤，則傳回零或負數。

#read

用法為

$status = $z->read($buffer, $length)
$status = $z->read($buffer, $length, $offset)

$status = read($z, $buffer, $length)
$status = read($z, $buffer, $length, $offset)

嘗試讀取 $length 位元組的未壓縮資料到 $buffer 中。

此 read 方法形式與前一個形式之間的主要差異在於，此形式會嘗試傳回 完全 $length 位元組。此函式不會執行的唯一情況是遇到檔案結束或 I/O 錯誤。

傳回寫入 $buffer 的未壓縮位元組數，如果為檔案結束或發生錯誤，則傳回零或負數。

#getline

用法為

$line = $z->getline()
$line = <$z>

讀取單一行。

此方法完全支援使用變數 $/（或 $INPUT_RECORD_SEPARATOR 或 $RS，當使用 英文 時）來決定什麼構成一行的結尾。段落模式、記錄模式和檔案 slurp 模式都受到支援。

#getc

用法為

$char = $z->getc()

讀取單一字元。

#ungetc

用法為

$char = $z->ungetc($string)

#getHeaderInfo

用法為

$hdr  = $z->getHeaderInfo();
@hdrs = $z->getHeaderInfo();

此方法傳回雜湊參考（在純量內容）或清單或雜湊參考（在陣列內容），其中包含壓縮資料串流中每個標頭欄位的資訊。

#tell

用法為

$z->tell()
tell $z

傳回未壓縮的檔案偏移量。

#eof

用法為

$z->eof();
eof($z);

如果已到達壓縮輸入串流的結尾，則傳回 true。

#seek

$z->seek($position, $whence);
seek($z, $position, $whence);

提供 seek 功能的子集，限制為只能在輸入檔案/緩衝區中向前搜尋。嘗試向後搜尋會造成致命錯誤。

請注意，此模組中 seek 的實作並未提供對壓縮檔案/緩衝區的真正隨機存取。它的運作方式是從檔案/緩衝區中的目前偏移量解壓縮資料，直到到達 seek 參數中指定的未壓縮偏移量。對於非常小的檔案，這可能是可接受的行為。對於大型檔案，這可能會造成無法接受的延遲。

$whence 參數會採用一個常見值，即 SEEK_SET、SEEK_CUR 或 SEEK_END。

成功時傳回 1，失敗時傳回 0。

#binmode

用法為

$z->binmode
binmode $z ;

這是為了完整性而提供的空操作。

#opened

$z->opened()

如果物件目前參照已開啟的檔案/緩衝區，則傳回 true。

#autoflush

my $prev = $z->autoflush()
my $prev = $z->autoflush(EXPR)

如果 $z 物件與檔案或檔案控制代碼相關聯，則此方法會傳回基礎檔案控制代碼的目前自動快取設定。如果 EXPR 存在且非零，它會在每次寫入/列印操作後啟用快取。

如果 $z 與緩衝區相關聯，則此方法沒有作用，且總是傳回 undef。

請注意，特殊變數 $| 無法 用於設定或擷取自動快取設定。

#input_line_number

$z->input_line_number()
$z->input_line_number(EXPR)

傳回目前的未壓縮行號。如果存在 EXPR，它會設定行號。請注意，設定行號並不會變更目前在正在讀取的檔案/緩衝區中的位置。

$/ 的內容用於判斷什麼構成行終止符。

#fileno

$z->fileno()
fileno($z)

如果 $z 物件與檔案或檔案處理相關聯，fileno 會傳回基礎檔案描述符。一旦呼叫 close 方法，fileno 會傳回 undef。

如果 $z 物件與緩衝區相關聯，這個方法會傳回 undef。

#close

$z->close() ;
close $z ;

關閉輸出檔案/緩衝區。

對於大多數版本的 Perl，如果 IO::Uncompress::Bunzip2 物件被銷毀（明確地或透過變數的參考超出範圍），這個方法會自動呼叫。例外是 Perl 版本 5.005 到 5.00504 和 5.8.0。在這些情況下，close 方法會自動呼叫，但直到程式終止時所有現存物件的全球銷毀。

因此，如果您希望您的指令碼可以在所有版本的 Perl 上執行，您應該明確呼叫 close，而不是依賴自動關閉。

成功時傳回 true，否則傳回 0。

如果在建立 IO::Uncompress::Bunzip2 物件時已啟用 AutoClose 選項，且物件與檔案相關聯，基礎檔案也會被關閉。

#nextStream

用法為

my $status = $z->nextStream();

跳到輸入檔案/緩衝區中的下一個壓縮資料串流。如果找到新的壓縮資料串流，eof 標記會被清除，並且 $. 會重設為 0。

如果找到新的串流，傳回 1；如果沒有找到，傳回 0；如果遇到錯誤，傳回 -1。

#trailingData

用法為

my $data = $z->trailingData();

在解壓縮完成後，傳回壓縮資料串流之後立即存在的資料（如果有）。只有在遇到壓縮資料串流的結尾後呼叫這個方法才有意義。

當壓縮資料串流後立即有有用的資訊，而且您不知道壓縮資料串流的長度時，可以使用此選項。

如果輸入是緩衝區，trailingData 將傳回從壓縮資料串流的結尾到緩衝區結尾的所有內容。

如果輸入是檔案句柄，trailingData 會傳回壓縮資料串流結束後留在檔案句柄輸入緩衝區的資料。接著你可以使用檔案句柄來讀取輸入檔案的其餘部分。

如果輸入是檔案名稱，請勿使用 trailingData。

如果您在開始解壓縮之前知道壓縮資料串流的長度，您可以透過在建構函式中設定 InputLength 選項來避免使用 trailingData。

#Importing

目前 IO::Uncompress::Bunzip2 不需要任何符號常數。

#:all

匯入 bunzip2 和 $Bunzip2Error。與執行下列動作相同

use IO::Uncompress::Bunzip2 qw(bunzip2 $Bunzip2Error) ;

#範例

#與 Net::FTP 合作

請參閱 IO::Compress::FAQ

#支援

一般回饋/問題/錯誤報告應傳送至 https://github.com/pmqs/IO-Compress/issues（優先）或 https://rt.cpan.org/Public/Dist/Display.html?Name=IO-Compress。

#另請參閱

Compress::Zlib、IO::Compress::Gzip、IO::Uncompress::Gunzip、IO::Compress::Deflate、IO::Uncompress::Inflate、IO::Compress::RawDeflate、IO::Uncompress::RawInflate、IO::Compress::Bzip2、IO::Compress::Lzma、IO::Uncompress::UnLzma、IO::Compress::Xz、IO::Uncompress::UnXz、IO::Compress::Lzip、IO::Uncompress::UnLzip、IO::Compress::Lzop、IO::Uncompress::UnLzop、IO::Compress::Lzf、IO::Uncompress::UnLzf、IO::Compress::Zstd、IO::Uncompress::UnZstd、IO::Uncompress::AnyInflate、IO::Uncompress::AnyUncompress

IO::Compress::FAQ

File::GlobMapper、Archive::Zip、Archive::Tar、IO::Zlib

bzip2 程式的主要網站為 https://sourceware.org/bzip2/。

請參閱模組 Compress::Bzip2

#作者

此模組由 Paul Marquess 編寫，pmqs@cpan.org。

#修改記錄

請參閱 Changes 檔案。

#版權和授權

版權所有 (c) 2005-2023 Paul Marquess。保留所有權利。

此程式為自由軟體；您可以在與 Perl 相同的條款下重新散布或修改它。

Perldoc 瀏覽器由 Dan Book (DBOOK) 維護。如果您對網站本身、搜尋或文件呈現有任何問題，請透過 GitHub 問題追蹤器 或 電子郵件與他聯繫。

Perl 文件由 Perl 5 Porters 在 Perl 開發中維護。請透過 Perl 問題追蹤器、郵件清單 或 IRC 與他們聯繫，以回報文件內容或格式的任何問題。